Bjr à tous,
 
Mon probleme est assez répendu, je sais, mais les solutions apportées ne fonctionnent pas.
J'administre un réseau avec un serveur de messagerie (Exchange 2000) et je me trouve à croiser des clients ayant leur Bal sous Outlook 2000 dont les dossiers sont en anglais (Inbox, Deleted Items .....). Alors, j'ai bien sur cherché à régler le problème en utilisant la commande "Outlook.exe /resetfoldernames". J'étais bien content d'avoir trouvé cette soluce, vu qu'on ne croise pas souvent ce genre de problème sur les forums.....
 
Mais, MALHEUR , cette commande ne fonctionne pas sous Outlook 2000. Windows m'insulte en me disant que le commutateur n'existe pas pour Outlook 2000 !!!! Alors je cherche qqun qui connaitrait la soluce pour la version 2000 de mon logiciel de messagerie.
Merci d'avance....

J'avais eu le même problème sous outlook2000. En fouinant sur les forums, j'ai trouvé un thread où quelqu'un avait déposé un script vbs pour renommer les dossiers (je ne sais plus qui ni sur quel forum).
Ca a bien marché chez moi
 
-----
 
Set myOlApp = CreateObject("Outlook.application" )  
Set mynamespace = myOlApp.GetNamespace("MAPI" )  
reponse = MsgBox("voulez-vous renommer vos dossiers Outlook en français", 1, "Renommage des dossiers" )  
If reponse = vbOK Then  
        mynamespace.GetDefaultFolder(9).Name = "Calendrier"  
        mynamespace.GetDefaultFolder(10).Name = "Contacts"  
        mynamespace.GetDefaultFolder(3).Name = "Eléments supprimés"  
        mynamespace.GetDefaultFolder(16).Name = "Brouillons"  
        mynamespace.GetDefaultFolder(6).Name = "Boîte de réception"  
        mynamespace.GetDefaultFolder(11).Name = "Journal"  
        mynamespace.GetDefaultFolder(12).Name = "Notes"  
        mynamespace.GetDefaultFolder(4).Name = "Boîte d'envoi"  
        mynamespace.GetDefaultFolder(5).Name = "Eléments envoyés"  
        mynamespace.GetDefaultFolder(13).Name = "Tâches"  
End If  
 
-----

Le VBS fournis par µsoft qui vas bien :
 
' ----------------------------------------------------------------
' Programme : RenameMAPIFolders.vbs
' Date création : 11/01/2000
' Numéro de version: 1.0
' Auteur : Microsoft Consulting Services
' ----------------------------------------------------------------
' Programme de création/renommage des dossiers par défaut
' (en Français) pour une boite aux lettres donnée :
' %1 = Nom du serveur Exchange où sont les bàls
' %2 = Pseudonyme de la boîte aux lettres à traiter
' ----------------------------------------------------------------
Option Explicit
 
Const LocaleId=1036 'Français (Standard)
' Liste des principaux LocaleIds
' French - Standard 0x40C (1036)
' English US  0x409
' English UK  0x809
' German - Standard 0x407
' Italian   0x410
 
Const CodePage=1252 'Windows (Mutilingual)
 
Const CdoDefaultFolderInbox  = 1        'Inbox  
Const CdoDefaultFolderOutbox  = 2       'Outbox  
Const CdoDefaultFolderSentItems = 3     'Sent Items  
Const CdoDefaultFolderDeletedItems = 4  'Deleted Items  
 
Const CdoDefaultFolderCalendar = 0      'Calendar  
Const CdoDefaultFolderContacts = 5      'Contacts  
Const CdoDefaultFolderJournal = 6       'Journal  
Const CdoDefaultFolderNotes = 7         'Notes  
Const CdoDefaultFolderTasks  = 8        'Tasks  
 
Const szInbox = "Boîte de réception"
Const szOutbox = "Boîte d'envoi"
Const szSentItems = "Eléments envoyés"
Const szDeletedItems = "Eléments supprimés"
 
Const szCalendar = "Calendrier"
Const szContacts = "Contacts"
Const szJournal = "Journal"
Const szNotes = "Notes"
Const szTasks = "Tâches"
 
Dim szServer, szMailbox
Dim mapiSession
Dim ObjFolder
 
' Récupération des arguments : RenameMAPIFolders.vbs NomServer PseudonymeBoîteAuxLettres
If WScript.Arguments.Count <> 2 Then
 WScript.Echo "Usage:  cscript|wscript RenameMAPIFolders.vbs NomServer Pseudonyme"
 WScript.Quit
End If
 
szServer = WScript.Arguments(0)
szMailbox = WScript.Arguments(1)
 
Set mapiSession = CreateObject("MAPI.Session" )
mapiSession.SetLocaleIDs LocaleId, CodePage
 
mapiSession.Logon , , , , , , szServer & vbLf & szMailbox
 
' On teste la langue du dossier "Inbox"..  
if mapiSession.Inbox.Name = szInbox then
 WScript.Echo szMailbox & " - OK"
else
 WScript.Echo szMailbox & " - renommage des dossiers en cours"
 ' Renommer les différents dossiers par défaut (4 dossiers par défaut)
 Set objFolder = mapiSession.GetDefaultFolder(CdoDefaultFolderInbox)
        objFolder.Name = szInbox
 Set objFolder = mapiSession.GetDefaultFolder(CdoDefaultFolderOutbox)
        objFolder.Name = szOutbox
 Set objFolder = mapiSession.GetDefaultFolder(CdoDefaultFolderSentItems)
        objFolder.Name = szSentItems
 Set objFolder = mapiSession.GetDefaultFolder(CdoDefaultFolderDeletedItems)
        objFolder.Name = szDeletedItems
 
 ' Autres dossiers Outlook
 Set objFolder = mapiSession.GetDefaultFolder(CdoDefaultFolderCalendar)
       objFolder.Name = szCalendar
 Set objFolder = mapiSession.GetDefaultFolder(CdoDefaultFolderContacts)
       objFolder.Name = szContacts
 Set objFolder = mapiSession.GetDefaultFolder(CdoDefaultFolderJournal)
       objFolder.Name = szJournal
 Set objFolder = mapiSession.GetDefaultFolder(CdoDefaultFolderNotes)
       objFolder.Name = szNotes
 Set objFolder = mapiSession.GetDefaultFolder(CdoDefaultFolderTasks)
       objFolder.Name = szTasks
 set objFolder = nothing
 if mapiSession.Inbox.Name = szInbox then
  WScript.Echo szMailbox & " - renommage OK"
 else
  WScript.Echo szMailbox & " - erreur lors du renommage"
 end if
end if
 
mapiSession.Logoff
set mapiSession = nothing
 
Wscript.Echo "Terminé !"
 
Il renome tout sauf le repertoire "Brouillion" il le laisse en "Draft"

Merci pour les infos.... je vais essayer cela dès mon retour au boulot, c'est à dire lundi. Je vous tiens au courant de l'évolution. Merci les gars. Je suis toujours ouvert à d'autres solutions. Ces scripts vont bcp m'aider, mais j'ai à peu près 400 machines à vérifier. L'idéal, c'est que j'aie à faire la manip directement à la connection du client.
Mais les script me sont d'un très grand secours. Ca ne va pas m'empecher de m'ateler à la tâche dès lundi matin.
 
Merci encore

J'ai essayé la manip qui m'a été proposée. Elle fonctionne, mais ça reste fastidieux....  
Je cherche donc un moyen de réinitialiser les paramètres de boite aux lettres par le réseau chez mes clients.....
Je ne sais plus quoi faire et je tourne en rond....
Et du côté du serveur Exchange, y a t'il qqchose à faire ?