Envoyer un mailing en utilisant une macro Word et y ajouter une pièce jointe .
 
 
Sub publipostageMailing_wordVBA_avecPieceJointe()
'michelxld le 03.03.2006
'
'Utilisez cette procédure apres avoir créé et mis en forme votre document principal.
'C'est la macro qui va boucler sur tous les enregistrements et envoyer les mails et y ajouter une pièce jointe .
'Les adresses mail sont dans le champ "champMail" de la base de données .
'Cet exemple ne prend pas en compte les filtres éventuels dans le publipostage .
'
'Necessite d'activer la reference Microsoft Outlook xx.x Object Library
'
Dim outApp As Outlook.Application
Dim oItem As Outlook.mailItem
Dim leSujet As String, leDestinataire As String
Dim i As Integer
 
 
Set outApp = createObject("Outlook.Application" )
leSujet = "Essai de publipostage VBA avec pieces jointes"
 
 
'Afficher le 1er enregistrement du publipostage
thisDocument.mailMerge.dataSource.activeRecord = wdFirstRecord
 
 
'boucle sur tous les enregistrements de la base de données
For i = 1 To thisDocument.mailMerge.dataSource.recordCount
'récupération des adresses mail qui sont dans le champ "champMail"
leDestinataire = thisDocument.mailMerge.dataSource.dataFields("champMail" ).Value
 
 
Set oItem = outApp.createItem(olMailItem)
 
 
With oItem
.Subject = leSujet
.Body = thisDocument.Content 'insère le contenu du document dans le corps du message
.To = leDestinataire
'ajout d'un fichier attaché
.Attachments.Add "C:\maPieceJointe.txt"
.Send 'envoi du mail
End With
 
 
'pour passer à l'enregistrement suivant
thisDocument.mailMerge.dataSource.activeRecord = wdNextRecord
Set oItem = Nothing
Next i
 
 
Set outApp = Nothing
End Sub