SGBD / ASP : Page tester des procédures stockées SQL Server depuis ASP

SGBD / ASP : Page tester des procédures stockées SQL Server depuis ASP - SQL/NoSQL - Programmation

Marsh Posté le 21-07-2005 à 09:54:58    

Salut,
 
Hier, j'étais confronté à un gros problème de performances sur un site qu'on vient de passer en production.
 
Afin de vérifier la rapidité des procédures stockées entre le serveur BDD et IIS, j'ai donc dû créer une page qui execute des procédures stockées, charge le résultat, et indique en combien de temps ça a tourné.
 
=> Etant donné que pour mon "bench", j'avais décidé de tester 10 procédures différentes, chacune plusieurs fois avec des paramètres différents, j'ai décidé de faire une page générique, qui permette de sasir le nom de la PS a executer, ainsi que ses paramètres, mais tout en conservant l'utilisation de l'objet ADODB.Command (donc pas de exec de bourrin).
 
Voici le code de la page, qui pourrait vous être utile aussi.
Il reste à rajouter les autres types de données (pour le moment, elle n'accepte que les type Int, Varchar et DateTime) ainsi que les contrôles de base, genre si la PS existe, ou si on tente de lancer une PS en oubliant un paramètre obligatoire.
 

Code :
  1. <%@Language="VBScript"%>
  2. <%
  3. Option Explicit
  5. ' 1 heure, ça devrait suffir...
  6. Server.ScriptTimeout = 3600
  8. Dim fVal(1)
  9. fVal(0) = timer
  10. %>
  11. <html>
  12. <head>
  13.  <title>Page de test SQL</title>
  14. </head>
  15. <body>
  16. <%
  17. If Request.Form = "" Then
  18. ' Affichage d'un formulaire de saisie de la procédure et des paramètres
  19. %>
  20.  <p>Veuillez sasir le nom d'une procédure stockée à executer, ainsi que la liste des paramètres (un par ligne, sous la forme "@nomParam=valeur" ).<br>Tapez "(null)" pour les valeurs nulles.
  21.  <form name="frmSQL" method="POST">
  22.   <dl>
  23.    <dt>Procédure :</dt>
  24.    <dd><input size="47" type="text" name="procname"></dd>
  25.    <dt>Paramètres :</dt>
  26.    <dd><textarea name="params" cols="40" rows="5"></textarea></dd>
  27.    <dd><input type="submit" value="Lancer la procédure"></dd>
  28.   </dl>
  29.  </form>
  30. <%
  31. Else
  32. ' Affichage des résultats
  33. Dim tabParams
  34. Dim tabParamNames()
  35. Dim tabParamVals()
  36. tabParams = Split(CStr(Request.Form("params" )), vbCrLf)
  37. Redim tabParamNames(UBound(tabParams))
  38. Redim tabParamVals(UBound(tabParams))
  40. Dim i
  41. For i = LBound(tabParams) to UBound(tabParams)
  42.  tabParamNames(i) = Trim(Left(tabParams(i), Instr(1, tabParams(i), "=" ) - 1))
  43.  tabParamVals(i) = Trim(Right(tabParams(i), Len(tabParams(i)) - Instr(1, tabParams(i), "=" )))
  44.  If tabParamVals(i) = "(null)" Then
  45.   tabParamVals(i) = null
  46.  End If
  47. Next
  48. Dim cnx
  49. Set cnx = Server.CreateObject("ADODB.Connection" )
  50. cnx.ConnectionString = "dsn=LE_DSN;user id=LOGIN;password=PASSWORD"
  51. cnx.Open
  53. Dim cmd
  54. Set cmd = Server.CreateObject("ADODB.Command" )
  55. Set cmd.ActiveConnection = cnx
  56. cmd.NamedParameters = True
  57. cmd.CommandText = Request.Form("procname" )
  58. cmd.CommandType = 4
  59. cmd.CommandTimeout = 0
  60. %>
  61.  <p>Paramètres reçus :</p>
  62.  <pre>
  63. <%
  64. Dim rs
  65. Set rs = Server.CreateObject("ADODB.RecordSet" )
  66. Set rs.ActiveConnection = cnx
  67. For i = LBound(tabParams) to UBound(tabParams)
  68.  rs.Open "select c.name, c.xtype, c.length from syscolumns c, sysobjects o where o.xtype = 'P' and o.name like '" & Request.Form("procname" ) & "' and c.id = o.id and c.name like '" & tabParamNames(i) & "'"
  69.  Response.Write tabParamNames(i) & " = "
  70.  If Not isNull(tabParamVals(i)) Then
  71.   Response.Write tabParamVals(i)
  72.  Else
  73.   Response.Write "(null)"
  74.  End If
  75.  If Not rs.EOF Then
  76.   If rs("xtype" ) = 56 Then
  77.    Response.Write " Int"
  78.    cmd.Parameters.Append cmd.CreateParameter(rs("name" ), 3, 1, rs("length" ), tabParamVals(i))
  79.   ElseIf rs("xtype" ) = 167 Then
  80.    Response.Write " VarChar"
  81.    cmd.Parameters.Append cmd.CreateParameter(rs("name" ), 200, 1, rs("length" ), tabParamVals(i))
  82.   ElseIf rs("xtype" ) = 61 Then
  83.    Response.Write " DateTime"
  84.    cmd.Parameters.Append cmd.CreateParameter(rs("name" ), 135, 1, rs("length" ), tabParamVals(i))
  85.   End If
  86.   Response.Write vbCrLf
  87.  Else
  88.   Response.Write " Inexistant =&gt; ignoré"
  89.  End If
  90.  rs.Close
  91. Next
  92. %>
  93.  </pre>
  94. <%
  95. Set rs = cmd.Execute
  96. %>
  97.  <table>
  98.   <tr>
  99. <%
  100. Dim el
  101. For Each el in rs.Fields
  102. %>
  103.    <th><%=el.Name%></th>
  104. <%
  105. Next
  106. %>
  107.   </tr>
  108. <%
  109. Dim cpt
  110. cpt = 0
  111. Do While Not rs.EOF
  112.  cpt = cpt + 1
  113.  If cpt <= 100 Then
  114. %>
  115.   <tr>
  116. <%
  117.   For Each el in rs.Fields
  118. %>
  119.    <td><%=el.Value%></td>
  120. <%
  121.   Next
  122. %>
  123.   </tr>
  124. <%
  125.  End If
  126.  rs.MoveNext
  127. Loop
  128. If cpt > 100 Then
  129. %>
  130.   <tr>
  131.    <th colspan="<%=rs.Fields.Count%>"><%=cpt%> &eacute;l&eacute; au total</th>
  132.   </tr>
  133. <%
  134. End If
  135. %>
  136.  </table>
  137.  <a href="procrunner.asp">Autre requête</a>
  138. <%
  139. rs.Close
  140. Set rs = Nothing
  141. Set cmd = Nothing
  142. cnx.Close
  143. Set cnx = Nothing
  144. End If
  146. fVal(1) = CSng( timer )
  147. %>
  148.  <p>Dur&eacute; totale : <%=(fVal(1) - fVal(0))%> secondes.</p>
  149. </body>
  150. </html>


 
Actuellement, elle utilise un DSN, on pourrait très bien modifier cette ligne pour passer par une connection OLE DB.
 
Si vous êtes intéressés pour faire la même page en d'autres langages / pour d'autres SGBD, ce serait intéressant de se constituer une petite librairie dans ce topic non ?

Reply

Marsh Posté le 21-07-2005 à 09:54:58   

Reply

Marsh Posté le 21-07-2005 à 11:04:53    

J'aime bien, à chaque fois que je fais des topics "utiles", tout le monde s'en fout :spamafote:

Reply

Marsh Posté le 21-07-2005 à 12:21:07    

mais non bordel, c'est juste qu'il y a rien à dire de plus :o
j'ai quelques topics à toi dans mes favoris, spas pour ça que j'y ai posté hein


---------------
J'ai un string dans l'array (Paris Hilton)
Reply

Marsh Posté le 21-07-2005 à 12:22:06    

Ha, merci, ça fait plaisir :D

Reply

Sujets relatifs:

Leave a Replay

Make sure you enter the(*)required information where indicate.HTML code is not allowed